FactGrid:PAMCommercialLabels

From FactGrid
Jump to navigation Jump to search
1699958919516.jpg

Item:Q648370

The PAM Commercial Labels project aims at studying the visual representations produced according to customers's demands by the Papeteries Armoricaines et Morlaisiennes (PAM). The PAM was an important printing house located in Brest (Finistère, France). Started at the end of the 1920s, it ran for nearly a century and specialized in producing original commercial labels for shopkeepers based mainly in Brittany.

The PAM archives are preserved at the Centre de recherche bretonne et celtique (CRBC) in Brest (France).

Published introductory research : Image & Commerce de la fin du XIXe siècle à nos jours, dir. Maryse Cuzon, Philippe Jarnoux, Marie-Michèle Lucas & Florent Miane

Project members : Jean-Baptiste Pressac, Marie-Alice Le Corvec, Liliane Jaouen and Florent Miane.

Données créées dans le cadre de ce projet / Data created by the project

Calendrier de suivit du projet

Une fois validées, les données de type étiquette, personne, collectif, sont associées au projet : Saisie de Property:P131 = Item:Q648370.

  1. 120mn le 8 janvier 2024, JBP et MALC
  2. 150mn le 9 janvier 2024, JBP et MALC (durant ces deux jours, vérification de 53 étiquettes et 7 producteurs = 2mn30s par item)
  3. 30mn le 16 janvier 2024, JBP, MALC
  4. 60mn le 12 février 2024, JBP, MALC
  5. 45mn le 14 février 2024, JBP, MALC (jusqu'à Q746697)
  6. le 27 février 2024, JBP à partir de 16h40, tentative de validation mais FactGrid après avoir été inaccessible en début d'après-midi n'est plus éditable.
  7. 50mn le 4 mars 2024, JBP et MALC
  8. 45mn le 18 mars 2024, JBP et MALC
  9. 50mn le 2 avril 2024, JBP et MALC (reprendre à PAM 33.26.47 vers le plus récent)
  10. 30mn le 4 avril 2024, JBP et MALC
  11. 60mn le 8 avril 2024, JBP et MALC
  12. 60mn le 22 avril 2024, JBP et MALC (total : 700mn soit 11h 40mn)

Note : Deux exemplaires de Item:Q740390 ("LC / Granval / marque commerciale / vin de table / vin de différents Pays de la Communauté Européenne / 98 cl /11 % / Mis en bouteille pour les Ets Le Comte à Pontorson par 35000 Rennes / PAM Brest") étaient présentes dans la première boite. La notice de l'étiquette a été saisie et les deux exemplaires ont été remis dans la boite des L. Par contre, il faudra que Liliane pense à saisir la cote et le nombre d'exemplaires quand elle traitera cette boite.

A voir avec Liliane :

  1. Mettre des espaces entre les volumes et l'unité. Ex. 33 cl et non pas 33cl
  2. Faire des copier-coller pour les identifiants Iconclass

Points à aborder :

  1. Il manque à Liliane un type d'étiquette pour les boissons autres que le vin (sirops, boissons gazeuses)
  2. Il existe dans les boites des étiquettes qui n'ont pas été imprimées par la PAM

Bonnes pratiques de saisie dans FactGrid

Il n'est pas possible de vérifier les items créés par une personne donnée avec une requêtes SPARQL. Les requêtes de contrôle qualité passent donc par l'association des items Property:P131 avec le projet Item:Q648370.

Items créés dans le cadre du projet

Tous les items créés dans le cadre du projet et validés par MALC et JBP doivent avoir une Property:P131 = Item:Q648370.

Nombre d'items créés dans le cadre du projet

SELECT (COUNT(DISTINCT ?item) AS ?items_nbr) WHERE { ?item wdt:P131 wd:Q648370. }

Items sans label en français ou en anglais

A améliorer selon https://www.wikidata.org/wiki/Wikidata:SPARQL_query_service/queries/examples/maintenance#Missing_labels_for_a_target_language. 

# Source : https://www.wikidata.org/wiki/Wikidata:SPARQL_query_service/queries/examples/maintenance#Missing_labels_for_a_target_language
SELECT ?item (GROUP_CONCAT(LANG(?label); SEPARATOR = " ") AS ?langLabels) (GROUP_CONCAT(?label; SEPARATOR = " ~ ") AS ?labels) WHERE {
  ?item wdt:P131 wd:Q648370;
    rdfs:label ?label.
}
GROUP BY ?item
# Mettre en commentaire la ligne suivante pour afficher les labels et les langues des labels des items créés par le projet PAM
HAVING(!CONTAINS(STR(?langLabels), "fr") || !CONTAINS(STR(?langLabels), "en"))
ORDER BY DESC(?item)

Classes des items

SELECT ?item ?itemLabel (GROUP_CONCAT(?classe; SEPARATOR = " ~ ") AS ?classes) (GROUP_CONCAT(?classeLabel; SEPARATOR = " ~ ") AS ?classesLabels) WHERE {
  ?item wdt:P131 wd:Q648370;
    wdt:P2 ?classe.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?item rdfs:label ?itemLabel.
    ?classe rdfs:label ?classeLabel.
  }
}
GROUP BY ?item ?itemLabel
ORDER BY DESC (?item)

Étiquettes

  1. Les étiquettes doivent être instance de Item:Q453647 et d'une sous-classe de Item:Q516124; par exemple, Item:Q636311 (Wine label)
  2. Si le graphisme de l'étiquette est abstrait, saisir aussi Property:P991 = 0 (ex. Item:Q701890)
  3. Labels :
    1. Mettre des espaces entre les valeurs et les unités de mesure. Ex. 100 ml et non pas 100ml.
    2. Pour distinguer des étiquettes dont le texte est similaire mais avec des variantes telles que impression en mode portrait ou en mode paysage, écrire par ex. "11° / Réserve de l'Hôtel / vin de qualité supérieure / Imp. PAM. Brest." (alternative n°1)

Commanditaires

Les commanditaires (ou clients) des étiquettes doivent être saisis comme étant de nature Organisation.

Personnes

Pour l'instant, la création de personnes est suspendu.

Prénom inconnu

  1. Saisir comme label en anglais et en français : le nom de famille préfixé par N.N. (no name). Par ex. Item:Q636312
  2. Saisir une Property:P17 = Item:Q21406

Genre inconnu

Saisir une Property:P17 = Item:Q160236

SPARQL Queries for CRBC PAM labels collection

As the queries are currently being written, they are reproduced for the time being without a direct link to the Query service.

Labels in the CRBC PAM (Q636348) inventory

labels in the CRBC PAM (Q636348) inventory 

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P345 wd:Q636348;
    wdt:P2/wdt:P3* wd:Q516124. 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

labels in the CRBC PAM (Q636348) inventory, not yet associated to this project (before quality control) 

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P345 wd:Q636348;
    wdt:P2/wdt:P3* wd:Q516124.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  FILTER NOT EXISTS {?item wdt:P131 wd:Q648370.}
}

Typefaces

Wine labels and theirs typefaces 

# Wine labels and theirs typefaces
SELECT ?item ?itemLabel (GROUP_CONCAT(?policeLabel; SEPARATOR = " / ") AS ?policesLabels) WHERE {
  ?item wdt:P345 wd:Q636348.
  OPTIONAL { ?item wdt:P748 ?police. }
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?police rdfs:label ?policeLabel.
    ?item rdfs:label ?itemLabel.
  }
}
GROUP BY ?item ?itemLabel

Typefaces and number of wine labels using them 

# Typefaces and number of wine labels using them
# For the labels trick, see https://www.wikidata.org/wiki/Wikidata:SPARQL_tutorial#wikibase:Label_and_aggregations
SELECT ?typefaceLabel ?typeface (COUNT(?typeface) AS ?nbr) WHERE {
  ?item wdt:P345 wd:Q636348;
    wdt:P2 wd:Q636311.
  OPTIONAL { ?item wdt:P748 ?typeface. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?typeface ?typefaceLabel
ORDER BY DESC (?nbr)

Iconclass elements

Wine labels and their Iconclass elements

The URIs of the RDF resource representing the Iconclass elements could not be directly used in the query as those URIs are not encoded in UTF8 for historical reasons (according to Etienne Posthumus). For instance, the URI of 22C4(BROWN) is 

https://iconclass.org/22C4%28BROWN%29

. 

# PAM Wine labels and theirs Iconclass elements (ICE)
SELECT ?item ?itemLabel (GROUP_CONCAT(DISTINCT ?ICEpreflabel; SEPARATOR = " / ") AS ?ICEpreflabels) (GROUP_CONCAT(DISTINCT ?ICE_IRI; SEPARATOR = " / ") AS ?ICE_IRIs) WHERE {
  ?item wdt:P345 wd:Q636348.
  OPTIONAL { ?item wdt:P991 ?ICE_notation. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  BIND(URI(CONCAT("http://iconclass.org/", ?ICE_notation)) AS ?ICE_IRI)
  SERVICE <https://iconclass.org/sparql> {
    SELECT * WHERE {
      ?ICE skos:notation ?ICE_notation;
        skos:prefLabel ?ICEpreflabel.
    }
  }
}
GROUP BY ?item ?itemLabel

Most used Iconclass elements (ICE) 

# Most used Iconclass elements (ICE)
SELECT ?ICEpreflabel ?ICE_notation (COUNT(*) AS ?nbr) WHERE {
  ?item wdt:P345 wd:Q636348.
  OPTIONAL { ?item wdt:P991 ?ICE_notation. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  SERVICE <https://iconclass.org/sparql> {
    SELECT * WHERE {
      ?ICE skos:notation ?ICE_notation;
        skos:prefLabel ?ICEpreflabel.
    }
  }
}
GROUP BY ?ICEpreflabel ?ICE_notation
ORDER BY DESC (?nbr)

Commissioners and their locations

Commissioners and their locations (use map display) 

# Commissioners could have many locations
SELECT ?item ?itemLabel ?commissioner ?commissionerLabel (SAMPLE(?localization) AS ?localization) (SAMPLE(?localizationLabel) AS ?localizationLabel) (SAMPLE(?coordinates) AS ?coordinates) WHERE {
  ?item wdt:P345 wd:Q636348;
    wdt:P2 wd:Q636311;
    wdt:P273 ?commissioner.
  ?commissioner wdt:P47 ?localization.
  ?localization wdt:P48 ?coordinates.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel ?commissioner ?commissionerLabel

Queries in project

  1. Other printers than PAM
Retrieved from "https://database.factgrid.de/w/index.php?title=FactGrid:PAMCommercialLabels&oldid=8423512"