FactGrid:PAMCommercialLabels

Item:Q648370

The PAM Commercial Labels project aims at studying the visual representations produced according to customers's demands by the Papeteries Armoricaines et Morlaisiennes (PAM). The PAM was an important printing house located in Brest (Finistère, France). Started at the end of the 1920s, it ran for nearly a century and specialized in producing original commercial labels for shopkeepers based mainly in Brittany.

The PAM archives are preserved at the Centre de recherche bretonne et celtique (CRBC) in Brest (France).

Published introductory research : Image & Commerce de la fin du XIXe siècle à nos jours, dir. Maryse Cuzon, Philippe Jarnoux, Marie-Michèle Lucas & Florent Miane

Project members : Jean-Baptiste Pressac, Marie-Alice Le Corvec, Liliane Jaouen and Florent Miane.

Bonnes pratiques de saisie dans FactGrid

Une fois validées, les données de type étiquette, personne, collectif, sont associées au projet : Saisie de Property:P131 = Item:Q648370.

Personnes

Prénom inconnu

1. Saisir comme label en anglais et en français : le nom de famille préfixé par N.N. (no name). Par ex. Item:Q636312
2. Saisir une Property:P17 = Item:Q21406

Genre inconnu

Saisir une Property:P17 = Item:Q160236

SPARQL Queries for CRBC PAM labels collection

As the queries are currently being written, they are reproduced for the time being without a direct link to the Query service.

Wine labels in the CRBC PAM (Q636348) inventory

Wine labels in the CRBC PAM (Q636348) inventory

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P345 wd:Q636348;
    wdt:P2 wd:Q636311.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Typefaces

Wine labels and theirs typefaces

# Wine labels and theirs typefaces
SELECT ?item ?itemLabel (GROUP_CONCAT(?policeLabel; SEPARATOR = " / ") AS ?policesLabels) WHERE {
  ?item wdt:P345 wd:Q636348.
  OPTIONAL { ?item wdt:P748 ?police. }
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?police rdfs:label ?policeLabel.
    ?item rdfs:label ?itemLabel.
  }
}
GROUP BY ?item ?itemLabel

Typefaces and number of wine labels using them

# Typefaces and number of wine labels using them
# For the labels trick, see https://www.wikidata.org/wiki/Wikidata:SPARQL_tutorial#wikibase:Label_and_aggregations
SELECT ?typefaceLabel ?typeface (COUNT(?typeface) AS ?nbr) WHERE {
  ?item wdt:P345 wd:Q636348;
    wdt:P2 wd:Q636311.
  OPTIONAL { ?item wdt:P748 ?typeface. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?typeface ?typefaceLabel
ORDER BY DESC (?nbr)

Iconclass elements

Wine labels and their Iconclass elements

# PAM Wine labels and their Iconclass elements (ICE)
SELECT ?item ?itemLabel (GROUP_CONCAT(DISTINCT ?ICEpreflabel; SEPARATOR = " / ") AS ?ICEpreflabels) WHERE {
  ?item wdt:P345 wd:Q636348.
  OPTIONAL { ?item wdt:P991 ?ICE_notation. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  SERVICE <https://iconclass.org/sparql> {
    SELECT * WHERE {
      ?ICE skos:notation ?ICE_notation;
        skos:prefLabel ?ICEpreflabel.
    }
  }
}
GROUP BY ?item ?itemLabel

Most used Iconclass elements (ICE)

# Most used Iconclass elements (ICE)
SELECT ?ICEpreflabel (COUNT(*) AS ?nbr) WHERE {
  ?item wdt:P345 wd:Q636348.
  OPTIONAL { ?item wdt:P991 ?ICE_notation. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  SERVICE <https://iconclass.org/sparql> {
    SELECT * WHERE {
      ?ICE skos:notation ?ICE_notation;
        skos:prefLabel ?ICEpreflabel.
    }
  }
}
GROUP BY ?ICEpreflabel
ORDER BY DESC (?nbr)

Commissioners and their locations

Commissioners and their locations (use map display)

SELECT ?item ?itemLabel ?commissioner ?commissionerLabel ?localization ?localizationLabel ?coordinates WHERE {
  ?item wdt:P345 wd:Q636348;
    wdt:P2 wd:Q636311;
    wdt:P273 ?commissioner.
  ?commissioner wdt:P47 ?localization.
  ?localization wdt:P48 ?coordinates .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Queries in project

1. Other printers than PAM